====== Windows: scripts manage wow ======
\\

**change to addons folder**
<file dos>
@echo off
d:
cd D:\Games\World of Warcraft\_retail_\Interface\AddOns\
</file>


**zip addon**
<file dos>
@echo off


IF [%1]==[] (
	ECHO syntax: zip_addon.bat addon_name [subver]
	goto end
)

IF [%2]==[] (
	SET sufx="01"
) ELSE ( 
	SET sufx=%2
)

SET mydate=%date:~10,4%%date:~4,2%%date:~7,2%
SET file=%1
SET versione=1007-%mydate%%sufx%

tar.exe -a -cvf %1-%versione%.zip %1
dir %1-%versione%.zip

:end
</file>

**clean orphans configs**
<file dos>
@echo off
pushd "D:\Games\World of Warcraft\_retail_\WTF\Account"

del /s *.bak
del /s *.old

for /d %%i in (*) do (
	if exist %%i\SavedVariables\ (
		echo Account: %%i

		for %%j in ("%%i\SavedVariables\*.lua") do (
			echo %%~nj | findstr /r /i "^Blizzard_" > nul
			if errorlevel 1 (
				echo GlobalSV: %%~nj
				if not exist ..\..\Interface\AddOns\%%~nj\ (
					echo Delete: %%~nj
					del "%%j"
				)
			)
		)

		for /d %%j in ("%%i\*") do (
			for /d %%k in ("%%j\*") do (
				echo Character: %%k
				for %%l in ("%%k\SavedVariables\*.lua") do (
					echo %%~nl | findstr /r /i "^Blizzard_" > nul
					if errorlevel 1 (
						echo CharSV: %%~nl
						if not exist ..\..\Interface\AddOns\%%~nl\ (
							echo Delete: %%~nl
							del "%%l"
						)
					)
				)
			)
		)
	)
)

popd
pause
</file>



---\\ return to gimbo wiki [[:start|home page]]
~~NOCACHE~~